::ReaderTop, Main, Index

proc ::Reader::Open {fileName args} {

    # Open an Acrobat Reader instance.
    #
    # fileName - File name of PDF file to open.
    # args     - Options described below.
    #
    # -nameddest <string> - Specify a named destination in the PDF document.
    # -page <int>         - Specify a numbered page in the document, using an integer value.
    #                       The first page of the document has a value of 1.
    # -zoom <int>         - Specify a zoom factor in percent.
    # -pagemode <string>  - Specify page display mode.
    #                       Valid values: bookmarks thumbs none
    # -search <string>    - Open the Search panel and perform a search for the
    #                       words in the specified string. You can search only for single words.
    #                       The first matching word is highlighted in the document.
    # -scrollbar <bool>   - Turn scrollbars on or off.
    # -toolbar <bool>     - Turn the toolbar on or off.
    # -statusbar <bool>   - Turn the status bar on or off.
    # -messages <bool>    - Turn document message bar on or off.
    # -navpanes <bool>    - Turn the navigation panes and tabs on or off.
    # -embed <frame>      - Embed the Reader instance into a Tk frame. This frame must
    #                       exist and must be created with option `-container true`.
    #
    # Use an already running instance, if available.
    #
    # Note, that above described options are only a subset of all available
    # command line parameters. For a full list, see:
    # <http://www.adobe.com/content/dam/Adobe/en/devnet/acrobat/pdfs/pdf_open_parameters.pdf>
    #
    # Returns no value.
    #
    # See also: OpenNew Quit

    Reader::_Init
    Reader::_Start $fileName false {*}$args
}

proc ::Reader::OpenNew {fileName args} {

    # Open a new Acrobat Reader instance.
    #
    # fileName - File name of PDF file to open.
    # args     - List of startup options and its values.
    #
    # For a detailed description of supported options see [Open].
    #
    # Returns no value.
    #
    # See also: Open Quit

    Reader::_Init
    Reader::_Start $fileName true {*}$args
}

proc ::Reader::Quit {} {

    # Quit all Acrobat Reader instances.
    #
    # Returns no value.
    #
    # See also: Open OpenNew

    variable readerProgName

    if { $readerProgName ne "" } {
        Cawt KillApp [file tail $readerProgName]
    }
}

proc ::Reader::SetReaderProg {fileName} {

    # Set the path to Acrobat Reader program.
    #
    # fileName - Full path name to Acrobat Reader program `AcroRd32.exe`
    #
    # Use this procedure, if the automatic detection of the path to
    # Acrobat Reader does not work.
    #
    # Note, that this procedure must be called before calling [Open] or [OpenNew].
    #
    # Returns no value.
    #
    # See also: Open OpenNew

    variable readerProgName

    set readerProgName $fileName
}